!* Build geometry
/PREP7  
RECTNG,0,10,0,8,
RECTNG,2,8,0,8, 
RECTNG,0,10,1,7
AOVLAP,ALL

!* Group geometry into components for ease
ASEL,S,,,12,12,1,0  !* select interior area
CM,CORE,AREA        !* call it CORE
ALLSEL,ALL          !* select everything
ASEL,S,,,4,11,1,0   !* select exterior areas
CM,SHELL,AREA       !* call them SHELL
ALLSEL,ALL          !* select everything

LSEL,S,,,25,32,1,0  !* select corners where temp is applied
CM,CORNERS,LINE     !* call them CORNERS
ALLSEL,ALL
LSEL,S,,,5,7,2,0    !* select convective edges
CM,CONVECT,LINE     !* call them CONVECT
ALLSEL,ALL
LSEL,S,,,10,12,2,0  !* select insulated edges
CM,INSUL,LINE       !* call them INSUL
ALLSEL,ALL

LSEL,S,,,13,14,1,0  !* start selecting smallest lines
LSEL,A,,,16,17,1,0  
LSEL,A,,,26,32,2,0
CM,SHORTY,LINE      !* call them SHORTY
ALLSEL,ALL
LSEL,S,,,19,20,1,0  !* start selecting medium lines
LSEL,A,,,22,22,1,0  
LSEL,A,,,23,31,2,0
CM,MIDDY,LINE       !* call them MIDDY
ALLSEL,ALL
LSEL,S,,,10,10,1,0  !* start selecting biggest lines
LSEL,A,,,5,7,2,0  
LSEL,A,,,12,24,3,0
CM,FATTY,LINE       !* call them FATTY
ALLSEL,ALL

!* Define material properties
MPTEMP,,,,,,,,      !* material 1, unobtainium
MPTEMP,1,0  
MPDATA,KXX,1,,10
MPTEMP,,,,,,,,      !* material 2, expensivite
MPTEMP,1,0  
MPDATA,KXX,2,,100   

!* Apply materials to areas  
CMSEL,S,CORE        !* select the CORE
AATT,1,,1,0         !* apply material 1
CMSEL,S,SHELL       !* select the SHELL
AATT,2,,1,0         !* apply material 2
ALLSEL,ALL          !* select everything

!* Select element type
ET,1,PLANE55

!* Specify element divisions on edges
CMSEL,S,SHORTY          !* select the SHORTY lines
LESIZE,ALL,,,4,,1,,,1,  !* 4 elements per line
CMSEL,S,MIDDY           !* select the MIDDY lines
LESIZE,ALL,,,6,,1,,,1,  !* 6 elements per line
CMSEL,S,FATTY           !* select the FATTY lines
LESIZE,ALL,,,20,,1,,,1, !* 20 elements per line
ALLSEL,ALL

!* Create mesh
MSHKEY,0                !* use free meshing
AMESH,ALL               !* mesh all areas

!* Apply boundary conditions
CMSEL,S,CORNERS         !* select the corners
DL,ALL,,TEMP,100,1      !* apply temp of 100
CMSEL,S,INSUL           !* select the insulted edges
SFL,ALL,HFLUX,0,        !* apply flux of 0
CMSEL,S,CONVECT         !* select the convection edges
SFL,ALL,CONV,10, ,50,   !* natural convection, h=10, T=50
ALLSEL,ALL
FINISH

!*  Solve the model
/SOLU   
/STATUS,SOLU
SOLVE   
FINISH

!* Create a cool temperature plot
/POST1  
SET,LAST
/EFACE,1
!*  
PLNSOL,TEMP, ,0,