OVERHILL
BRIEF ABSTRACT
We seek a minimal initial velocity on a projectile in order to clear a
hill and hit a target behind the hill.
GENERAL INFORMATION
FileName:   OVERHILL

Full title:   Clear the Hill, Hit the Target

Developers:  

Lynn Kiaer, Department of Mathematics,  Rose-Hulman Institute of Technology, Terre Haute IN 47803 USA.

Brian J. Winkel, Department of Mathematics,  Rose-Hulman Institute of Technology, Terre Haute IN 47803 USA.

Contact:  
Brian J. Winkel, Department of Mathematics,  Rose-Hulman Institute of Technology, Terre Haute IN 47803 USA.  Phone:  812-877-8412.  
Email:  winkel@rose-hulman.edu.   FAX:  812-877-3198.

Support:  
The production of this material is supported by the National Science Foundation under Division of Undergraduate Education grant DUE-9352849:  Development Site for Complex, Technology-Based Problems in Calculus with Applications in Science and Engineering and the Arvin Foundation of Columbus IN.
STATEMENT OF PROBLEM 
Suppose we are positioned at the origin (0, 0) and there is a flat field before us, then a hill which starts at (300, 0), rises linearly to a peak at 
T  = (350, 150) and then falls to (400, 0).  All distance in meters.    We wish to lob a projectile over the top of the hill (clearing it by at least one meter) and hit the point P = (375, 75) on the opposite side of the hill.
Determine the minimum initial velocity v0 such that our projectile can be fired over a mountain and hit a specific point on the opposite side of the mountain.
Plot the path of the projectile and the shape of the hill to confirm that the hill is cleared and the target hit.
Assume there is no air resistance in the flight of the projectile.
KEYWORDS  
Projectile motion, parametric equations, constraints.
TEACHER NOTES
ISSUES RELATED TO THE PROBLEM
View the problem as a constraint problem, not an optimization problem and you will be met with much success.  In fact, let the students work with the problem for a while as an optimization problem before suggesting constraints.  And be sure they argue why their constrained solution is an optimal one.
Prerequisites
Understanding of projectile motion.
Time allotment - time management
Expectations 
Future payoffs
Extensions
References and Sources
POSSIBLE SOLUTION
We construct a function which will give us the hill.
hill[x_] = If[x < 300, 0,
				If[x < 350, 3x - 900,
					If[x < 400, 1200-3x,0]]];
hillpic = Plot[hill[x],{x,0,500},
		PlotRange->{{0,500},{0,300}}]
We attempt to hit point pt  = (375,75) on the right side of the mountain from (0, 0).  We plot this point, the origin, and the hill.
pt = {375,hill[375]};
ptplot = Graphics[{PointSize[.02],Point[pt],Point[{0,0}]}];
hillplot = Show[hillpic,ptplot]
We presume there is no resistance and write out the equations for the x and y coordinate of two-dimensional projectile motion in terms of the initial velocity, v0, and the angle of launch, a, in radians.  We presume the initial position is (0, 0).
x[t_,a_,v0_] = v0 Cos[a] t;
y[t_,a_,v0_] = - 1/2 9.8 t^2 + v0 Sin[a] t;
We offer the parametric form of the trajectory with t, a, and v0 included.
P[t_,a_,v0_] = {x[t,a,v0],y[t,a,v0]};
We offer a  plot of hill and the trajectory in terms of the parameters a and v0.  This will permit exploration of various initial angles and velocities.
p[a_,v0_] := Show[hillplot,ParametricPlot[
				{x[t,a  ,v0], y[t,a ,v0]}, {t,0,20}]]
p[1,75]
-Graphics-
We eliminate the time parameter to get the trajectory in the form of a yc as a function of xc.
st = Solve[x[t,a,v0] == xc, t];
yc[xc_] = y[t,a,v0]/.st[[1]]
       2       2
-4.9 xc  Sec[a]
---------------- + xc Tan[a]
        2
      v0
We require projectile to hit (375, 75) and use this fact to eliminate one of the unknowns, say v0.
sol = Solve[yc[375]-75 == 0,v0]
           -135.554 Sec[a]                  135.554 Sec[a]
{{v0 -> ----------------------}, {v0 -> ----------------------}}
        Sqrt[-2. + 10. Tan[a]]          Sqrt[-2. + 10. Tan[a]]
Then we write the function G(a) and plot it (now of one variable a) we wish to zero out at 350, i.e. we wish to determine a such that G(a) = 0 or we just clear the top of the hill by 1 m, (from the fact that we demand yc(350) = 151).  
G[a_] = yc[350] - 151/.sol[[2]]
-151 + 350 Tan[a] - 32.6667 (-2. + 10. Tan[a])
Plot[G[a],{a,0,1.5}]
We find the value of a which makes the projectile just clear the top of the hill by 1 m.
solG = FindRoot[G[a]==0,{a,1.3}]
{a -> 1.30487}
We now claim we have the best angle, abest,  and the best initial velocity, vbest.
vbest = v0/.sol[[2]]/.solG[[1]]
87.5457
abest = a/.solG[[1]]
1.30487
And here is a plot of our best efforts.
p[abest, vbest]
We examine the trajectory of the projectile to see that is does clear the mountain and hit the point P without "entering" the mountain.
Show[hillplot,ParametricPlot[
				{x[t,abest,vbest], y[t,abest,vbest]}, 
				{t,0,20}],PlotRange->{{345,380},{50,180}}]
The real question is this:  Does requiring the projectile to just clear the mountain (yc(351) = 150 AND requiring the projectile to hit the point really insure the minimum velocity shot of all the shots which could clear (very high perhaps) the mountain and hit the point (375, 75)?
To which we answer, "Yes."
For if we lowered our angle at the same velocity or a lower velocity we would have hit the mountain. 
If we raised our angle, since the projectile is on its way down when it hits the desired point with this velocity the projectile will not reach as far as it did with the lower, abest, angle.
ISSUES IN SOLUTION
The proposers of this problem found it difficult to pin down the constraints of this problem because we tried to optimize some things rather than build constraints, see the results of this, and then argue these constraints yielded the best values.
Intuitively it appears that there is a best solution, and the drive to get the least initial velocity drives an optimization problem, but it is a problem best solved by constraints, not optimization.