POSSIBLE SOLUTION
1. Solve the differential equation v'(t) + k v(t) = 11 to find the runner's velocity as a function of time. Assume that the runner starts at rest. Integrate v(t) to find the runner's position as a function of time, assuming a zero starting position.
Input :=
sol = DSolve[{v'[t] == - k v[t] + 11,v[0]==0},v[t],t];
Input :=
vs[t_] = v[t]/.sol[[1]]
Output =
11 11
-- - ------
k k t
E k
Input :=
s[t_] = Integrate[vs[T],{T,0,t}]
Output =
-11 11 11 t
--- + ------- + ----
2 k t 2 k
k E k
2. We use the split times for Ben Johnson and Carl Lewis from the 100 meter final at the World Championships in Rome in 1987.
We first consider the Ben Johnson data.
We first enter the data and plot it.
Input :=
johnsondata = {{0,0}, {1.84, 10}, {2.86, 20}, {3.80, 30},
{4.67, 40},{5.53, 50}, {6.38, 60}, {7.23, 70}, {8.10, 80},
{8.96, 90},{9.83, 100}};
Input :=
jd = ListPlot[johnsondata,PlotStyle->{PointSize[.02]}]
Output =
-Graphics-
To try to adjust the constant k in your distance function to get the best fit to the data for each runner we offer the following plotting function which will plot the function s[t] for values of the constant k we want over the plot of the data.
Input :=
try[K_] := Show[Plot[s[t]/.{k->K},{t,0,10}],jd]
We try out several values of k and offer plots.
This one (k = 1) appears to be good.
Input :=
try[1]
Output =
-Graphics-
This one (k = .5) appears to be not so good.
Input :=
try[.5]
Output =
-Graphics-
We produce a sum of squares between the actual data and the predicted data (using the model s(t)) at the time splits. We to minimize parameter k in order to determine the best fitting model.
Input :=
SSj[k_] = Sum[(johnsondata[[i]][[2]] -
s[johnsondata[[i]][[1]]])^2,
{i,1, Length[johnsondata]}];
We plot SSj[k] to see if there is a reasonable starting value for our FindMinimum algorithm.
Input :=
Plot[SSj[k],{k,.6,1.5}]
Output =
-Graphics-
From this plot of SSj[k] it would appear that a value of k around .9 might make the sum of squares least.
Input :=
solj = FindMinimum[SSj[k],{k,.9}]
Output =
{8.85334, {k -> 0.976498}}
We identify Ben Johnson's constant at kj.
Input :=
kj = k/.solj[[2]];
We use the optimal parameter value for k in our model and plot and compare the model with the data.
Input :=
js[t_] = s[t]/.solj[[2]]
Output =
11.5359
-11.5359 + ----------- + 11.2647 t
0.976498 t
E
Input :=
jsPlot = Plot[js[t],{t,0,10}]
Output =
-Graphics-
Input :=
Show[jsPlot,jd]
Output =
-Graphics-
We now consider this same approach for Carl Lewis data.
We first enter the data and plot it.
Input :=
lewisdata = {{0,0}, {1.94, 10}, {2.96, 20}, {3.91, 30},
{4.78, 40},{5.64, 50}, {6.50, 60}, {7.36, 70}, {8.22, 80},
{9.07, 90},{9.93, 100}};
Then we plot the data.
Input :=
ld = ListPlot[lewisdata,PlotStyle->{PointSize[.02]}]
Output =
-Graphics-
We produce a sum of squares between the actual data and the predicted data (using the model s(t)) at the time splits with parameter k which we seek to minimize in order to determine the best fitting model.
Input :=
SSl[k_] = Sum[(lewisdata[[i]][[2]] -
s[lewisdata[[i]][[1]]])^2,
{i,1, Length[lewisdata]}];
We plot SSl[k] to see if there is a reasonable starting value for our FindMinimum algorithm.
Input :=
Plot[SSl[k],{k,.6,1.5}]
Output =
-Graphics-
From this plot of SSj[k] it would appear that a value of k around .9 might make the sum of squares least.
Input :=
soll = FindMinimum[SSl[k],{k,.9}]
Output =
{22.1652, {k -> 0.997061}}
We identify Carl Lewis' constant at kl.
Input :=
kl = k/.soll[[2]];
We use the optimal parameter value for k in our model and plot and compare the model with the data.
Input :=
ls[t_] = s[t]/.soll[[2]]
Output =
11.0649
-11.0649 + ----------- + 11.0324 t
0.997061 t
E
Input :=
lsPlot = Plot[ls[t],{t,0,10}]
Output =
-Graphics-
Input :=
Show[lsPlot,ld]
Output =
-Graphics-
We note that Johnson and Lewis have different constants.
Johnson's constant kj is:
Input :=
kj
Output =
0.976498
Lewis' constant kl is:
Input :=
kl
Output =
0.997061
They sure do not differ much, with Lewis's constant being slightly larger than Johnson's. (Does this mean Lewis is a better runner than Johnson?)
Recall the constant k is in the differential equation model
m*v'(t) = -m*k*v(t) + m*p(t)
and a bigger k may result from larger wind resistance due to body shape or internal "resistance" of the body to supply more energy at higher velocities. This could be part of the reason for Johnson's winning the race by 0.01 sec.
3. Once you have a reasonable estimate for the constant k, look at the function v(t). How does it behave as t tends to infinity? Is there a maximum speed for the runners? What is it?
We computer the velocity function for each runner: vj[t] for Johnson and vl[t] for Lewis.
Input :=
vj[t_] = js'[t]
Output =
11.2647
11.2647 - -----------
0.976498 t
E
Input :=
vl[t_] = ls'[t]
Output =
11.0324
11.0324 - -----------
0.997061 t
E
Both appear to be leveling off as the exponential terms both go to zero in their velocity formulae.
Input :=
jvPlot = Plot[vj[t],{t,0,10},PlotRange->{0,12}]
Output =
-Graphics-
Input :=
lvPlot = Plot[vl[t],{t,0,10},PlotRange->{0,12}]
Output =
-Graphics-
In fact if we take the Limit as t->Infinity we see what is rather obvious from the formulae.
Input :=
{jLimitVel,lLimitVel} = Limit[{vj[t],vl[t]}, t->Infinity]
Output =
{11.2647, 11.0324}
It appears the Johnson has a highter limiting velocity of 11.2647 m/sec while Lewis' limiting velocity is 11.0324 m/sec.