Problem 2. How long to hit the ground (assume linear drag.)
Since we took positive pointing down, we'll say that we start at position 0 and we wish to find out how long it takes to get to position 5000. In order to do this, we must determine the velocity and integrate to get the position.
Input :=
v0 = 0;
temp = Flatten[DSolve[{de1, v[0] == v0}, v[t], t]]
Output =
278.8
{v[t] -> 278.8 - -----------}
0.114778 t
E
Input :=
vel1[t_] = v[t] /. temp
Output =
278.8
278.8 - -----------
0.114778 t
E
Integrate to get the position function, pos1(t).
Input :=
po1 = .;
pos1[t_] = Integrate[vel1[t], t] + p01
Output =
2429.04
----------- + p01 + 278.8 t
0.114778 t
E
But we also need to find the constant of integration so that the position is 0 when t = 0, and we'll use Newton's method to get it.
Since the velocity is always positive, pos1[t] is increasing, so any guess for Newton's method will work: we guess 0. (We are assuming that the jump height, 0, corresponds to 0 feet from the plane and 5000 feet above ground.)
Input :=
FindRoot[pos1[0], {p01, 0}]
Output =
{p01 -> -2429.04}
Input :=
p01 = p01 /. %
Output =
-2429.04
Next we find the time when pos1[t] = 2000, i.e. the end of the first time period in which the sky diver is falling pointing perpendicular to the ground. Making use of monotonicity (see the graph), any guess with Newton's method (FindRoot[]) will do.
Input :=
Plot[pos1[t], {t, 0, 10}]
Output =
-Graphics-
Input :=
FindRoot[pos1[t] == 2000, {t, 10}]
Output =
{t -> 14.1736}
Input :=
t1 = t /. %
Output =
14.1736
So, it takes about 14 seconds before the sky diver "flies like an eagle".
We now use the velocity at t1 as the initial velocity for the time period in which she is falling spread eagle.
Input :=
v1 = vel1[t1];
temp = Flatten[DSolve[{de2, v[0] == v1}, v[t], t]]
Output =
43.6005
{v[t] -> 180.4 + -----------}
0.177384 t
E
Input :=
vel2[t_] = v[t] /. temp
Output =
43.6005
180.4 + -----------
0.177384 t
E
Integrate to get the position function, pos2(t).
Input :=
p02 = .;
pos2[t_] = Integrate[vel2[t], t] + p02
Output =
-245.798
----------- + p02 + 180.4 t
0.177384 t
E
Since the velocity is always positive, pos2(t) is increasing, so any guess for Newton's method will work: again we guess 0.
Input :=
FindRoot[pos2[0]==2000, {p02, 0}]
Output =
{p02 -> 2245.8}
Input :=
p02 = p02 /. %
Output =
2245.8
Next we find the time when pos2[t] = 4500 (500 feet above aground).
Input :=
Plot[pos2[t], {t, 0, 15}]
Output =
-Graphics-
Input :=
FindRoot[pos2[t] == 4500, {t, 12}]
Output =
{t -> 12.6403}
Input :=
t2 = t /. %
Output =
12.6403
So, it takes about 12.6 seconds before the sky diver opens her chute.
We now use the velocity at t2 as the initial velocity for the time period in which she is falling with her chute opened.
Input :=
v2 = vel2[t2];
temp = Flatten[DSolve[{de3, v[0] == v2}, v[t], t]]
Output =
163.712
{v[t] -> 21.32 + ----------}
1.50094 t
E
Input :=
vel3[t_] = v[t] /. temp
Output =
163.712
21.32 + ----------
1.50094 t
E
Integrate to get the position function, pos3(t).
Input :=
p03 = .;
pos3[t_] = Integrate[vel3[t], t] + p03
Output =
-109.073
---------- + p03 + 21.32 t
1.50094 t
E
Since the velocity is always positive, pos2[t] is increasing, so any guess for Newton's method will work: we guess 0.
Input :=
FindRoot[pos3[0]==4500, {p03, 0}]
Output =
{p03 -> 4609.07}
Input :=
p03 = p03 /. %
Output =
4609.07
Next, we find the time when pos3[t] = 5000 (on the aground).
Input :=
Plot[pos3[t], {t, 0, 20}]
Output =
-Graphics-
Input :=
FindRoot[pos3[t] == 5000, {t, 20}]
Output =
{t -> 18.3362}
Input :=
t3 = t /. %
Output =
18.3362
So, the Sky Diver will hit the ground in
Input :=
t1 + t2 + t3
Output =
45.1501
seconds with an average speed of
Input :=
5000 ft/(% sec) 3600 sec/(1 hr) 1 miles/(5280 ft)
Output =
75.5057 miles
-------------
hr
Below are the graphs of position, velocity and acceleration of the diver during her fall.
Input :=
pos[t_] := If[t < t1, pos1[t],
If[t < t1+t2, pos2[t-t1], pos3[t-t1-t2]]];
vel[t_] := If[t < t1, vel1[t],
If[t < t1+t2, vel2[t-t1], vel3[t-t1-t2]]];
Input :=
acc1[t_] = D[vel1[t], t];
acc2[t_] = D[vel2[t], t];
acc3[t_] = D[vel3[t], t];
acc[t_] := If[t < t1, acc1[t],
If[t < t1+t2, acc2[t-t1], acc3[t-t1-t2]]];
Input :=
Plot[pos[t], {t, 0, t1 + t2 + t3},
PlotRange -> All,
AxesLabel -> {"t [sec]", "distance fallen [ft]"}]
Output =
-Graphics-
Input :=
Plot[vel[t], {t, 0, t1 + t2 + t3},
PlotRange -> All,
AxesLabel -> {"t [sec]", "speed [ft/sec]"}]
Output =
-Graphics-
Input :=
Plot[acc[t], {t, 0, t1 + t2 + t3},
PlotRange -> All,
AxesLabel -> {"t [sec]", "acceleration [ft/sec^2]"}]
Output =
-Graphics-