The Logistic Map and Iterations.

The parametrized family of functions given by

Input := 

ClearAll[f, a, x];
f[x_, a_] = a x (1 - x);

is called the logistic family of maps, and is probably the most famous one dimensional maps in the study of chaotic dynamics. For each fixed a between 0 and
4, a member of the logistic family maps the interval between 0 and 1 into
itself. Here are plots of f[a,x] for
a = 1, 2, 3, and 4.

Input := 

Plot[Evaluate[Table[f[x, a], {a, 0, 4}]], {x, 0, 1},
 FrameLabel -> {"x", "y"}, AspectRatio -> Automatic,
 Frame -> True]

Output =

-Graphics-

We'll be interested in a process called iteration in which the output of a map is fed back into itself over and over again. That is, after choosing some value for a along with a starting value x between 0 and 1, we compute f[x, a], f[f[x, a], a], ... as shown below.

Input := 

a = 3; x = 0.5;

Input := 

f[x, a]
f[f[x, a], a]

Output =

0.75

Output =

0.5625

This process is accomplished compactly using the Mathematica function FoldList. With a = 3, here are the first 20 iterations of the point x = .5 (including the seed, 0.5.)

Input := 

FoldList[f, .5, Table[3, {20}]]

Output =

{0.5, 0.75, 0.5625, 0.738281, 0.579666, 0.73096, 0.589973, 
 
  0.725715, 0.597158, 0.721681, 0.602573, 0.718436, 0.606857, 
 
  0.715745, 0.610362, 0.71346, 0.613304, 0.711487, 0.61582, 
 
  0.709757, 0.618006}

Notice that this seems to be settling into a repetitive pattern of period 2.
Let's increase the value of a.

Input := 

FoldList[f, .5, Table[3.5, {20}]]

Output =

{0.5, 0.875, 0.382812, 0.826935, 0.500898, 0.874997, 0.38282, 
 
  0.826941, 0.500884, 0.874997, 0.38282, 0.826941, 0.500884, 
 
  0.874997, 0.38282, 0.826941, 0.500884, 0.874997, 0.38282, 
 
  0.826941, 0.500884}

Now we get a repeating pattern of period 4. If a were decreases, points would be attracted to a single value x satisfying x = f[x, a] called a fixed point. However, if a were increased again, we would see period 8, and then period 16, etc. This process is called period
doubling and culminates at the Feigenbaum Point (about a = 3.5699456718...).