BOXMAX
BRIEF ABSTRACT
We consider an extension of the problem of constructing a box by cutting four equal squares from a rectangle and folding to one in which the cutouts can be more general quadrilateral introducing another variable.
GENERAL INFORMATION
FileName:    BOXMAX

Full title:   Maximize volume of a box made from cutting corners off flat sheet and folding along resulting edges.

Last Revision Date:  31 May 1996.

Developer:   Brian J. Winkel, Department of Mathematical Sciences, United States Military Academy, West Point NY 10996 USA. Phone: 914-938-3200.  Email: ab3646@usma2.usma.edu.

FAX: 914-938-2409. 

Contact:  
Brian J. Winkel, Department of Mathematical Sciences, 
United States Military Academy, West Point NY 10996 USA.
Phone: 914-938-3200.  Email: ab3646@usma2.usma.edu.
FAX: 914-938-2409. 

Aaron D. Klebanoff, Department of Mathematics, 
Rose-Hulman Institute of Technology, Terre Haute IN 47803 USA.
Phone: 812-877-8151. Email: Aaron.Klebanoff@Rose-Hulman.Edu.
FAX: 812-877-3198. 

Support:  
The production of this material is supported by the National Science Foundation under Division of Undergraduate Education grant DUE-9352849:  Development Site for Complex, Technology-Based Problems in Calculus with Applications in Science and Engineering and the Arvin Foundation of Columbus IN.

STATEMENT OF PROBLEM 

We are given an 8 cm by 10 cm rectangular sheet of material and told to construct an open-topped box of maximum volume.


The simple case is one in which we make square cuts from each corner and fold to make a rectangular box.


Consider the more general case, in which we removecongruent quadrilaterals (wedges) from each corner of the sheet and fold the resulting figure so that the cut edges meet.


How does the maximum volume of the more general box compare with that of the rectangular box?


Hint: Place the sheet in the first quadrant with one vertex at the origin.  Draw a line from the origin, at an angle of Pi/4 (toward the point (1, 1)) of length L.  Call the endpoint of this line (a, a).  Now we will make our cuts from (b, 0) and (0, b) to (a, a), removing a quadrilateral from the corner.  We remove corresponding quadrilaterals from the other corners.


Note that if b<a we have a box with a larger top opening than base.  We do not have an edge which is perpendicular to the base - unless a = b.

KEYWORDS  

Visualization, optimization, volume, prism, function of two variables, function of a single variable, solid geometry.

TEACHER NOTES

ISSUES RELATED TO THE PROBLEM


Prerequisites


Visualization skills in three dimensions, formulating an objective function in two variables, optimizing a function of two variables.


Time allotment - time management


Two half periods in class with students using cut out models offered while working in groups.  Give students time, say  a week, to mull over problem, discuss with colleagues, and visit with instructor.  


First year calculus students found this  problem very hard because of the visualization problems encountered and the assumptions (quite often wrong) they jumped to on the dimensions, especially the height of the folded volume.  


Expectations 


Students will learn to visualize and defend visualizations to others as well as formulate a complex objective function from geometry.


Future payoffs


Students will be able to draw objects conceived in their brain and to build objective functions for optimization problems.


Extensions


This problem IS an extension of the traditional volume of a box from a flat sheet problem.


References and Sources

POSSIBLE SOLUTION(S)

The general case suggests that we make a square cut of length

 x = a in each corner but that we extend the edge back from the perpendicular cut by a distance y = b so that we do not have an edge which is perpendicular to the base when we fold the edges, but rather a more open box in which the top cross section is larger than the bottom cross section.  


If we do this we can see that we shall need the actual height of the box when we fold the edges.  This height (h) is one leg of a right triangle in which the other leg is b and the hypoteneuse is a, hence by Pythagorean Theorem we have h = Sqrt[a^2 - b^2].


Thus now we can "see" that our folded up volume consists of four kinds of pieces:


(1) the inner box of dimensions (8 - 2a), (10 - 2a), and h,

(2) two prisms of length 8 - 2a and triangle cross sections with legs 

	 b and h,

(3) two prisms of length 10 - 2a and triangle cross sections with 	     	legs  b and h, and

(4) four quarters of a pyramid each with square base b by b and 	     	height h.


We add up these volumes to get the total volume of our box. 


v[a_,b_] = (8-2a)(10-2a)Sqrt[a^2 - b^2] + 

				2  (8-2a) b Sqrt[a^2 - b^2]/2 +

				2  (10-2a) b Sqrt[a^2 - b^2]/2 +

				4 1/3 b^2 Sqrt[a^2 - b^2];


We offer a contour plot over the entire feasible region to help locate potential maxima.


ContourPlot[v[a,b](1 + Sign[a - b])/2,{a,0,4},{b,0,4}]



-ContourGraphics-


Thus we go after a maximum near a = 2 and y = b.  We set the partial derivatives with respect to a and b equal to zero.


va[a_,b_] = D[v[a,b],a]; vb[a_,b_] = D[v[a,b],b];


solc = FindRoot[{va[a,b]==0,vb[a,b]==0},{a,2},{b,1}]


{a -> 2.04789, b -> 1.08581}


Thus, ae, the square cut edge is 2.04789 cm.


ae = a/.solc[[1]]


2.04789


And, be, the back cut is 1.08581 cm.


be = b/.solc[[2]]


1.08581


The box then has a base of dimensions


baseLength = 10 - 2 ae


5.90423


baseWidth =  8 - 2 ae


3.90423


and a top of dimensions


topLength = baseLength + 2 be


8.07585


topWidth = baseWidth + 2 be


6.07585


And hence the maximum volume is 61.2466 cm^3 as seen below.


v[ae,be]


61.2466


We now draw a picture of the figure - presuming we lay the flat sheet on the x-y plane with one vertex at the origin and the 8 cm side along the x- and the 10 cm side along the y-axis.  Pi' are the points in the flat sheet which we cut into and form the bottom vertices of the box and the Qi's are the resulting top vertices.


P1 = {ae,ae,0}; P2 = {ae,10-ae,0}; 

P3 = {8-ae,10-ae,0}; P4 = {8-ae,ae,0};

Q1 = {ae-be,ae-be,Sqrt[ae^2 - be^2]}; 

Q2 = {ae-be,10-ae+be,Sqrt[ae^2 - be^2]};

Q3 = {8-ae+be,10-ae+be,Sqrt[ae^2 - be^2]};

Q4 = {8-ae+be,ae-be,Sqrt[ae^2 - be^2]}; 


picc = Show[Graphics3D[{PointSize[.02], Point[P1], 

     Point[P2], Point[P3], Point[P4],Point[Q1], 

     Point[Q2], Point[Q3], Point[Q4], 

     Thickness[.01], Line[{P1,P2}], Line[{P2,P3}], 

     Line[{P3,P4}], Line[{P4,P1}], Line[{Q1,Q2}], 

     Line[{Q2,Q3}], Line[{Q3,Q4}], Line[{Q4,Q1}], 

     Line[{P1,Q1}], Line[{P2,Q2}], Line[{P3,Q3}], 

     Line[{P4,Q4}] }],Boxed->False]



-Graphics3D-


We examine the square cut case when we cut a square piece out of each corner 


We set up the volume for a square cut of a by a from each of the corners.


rv[a_] = a (10 - 2a) (8-2a)


(8 - 2 a) (10 - 2 a) a


And maximize this volume.


sols = Solve[rv'[a]==0,a]//N


{{a -> 1.47247}, {a -> 4.52753}}


Thus we should cut in an edge of length 1.47247.


ae = a/.sols[[1]]



1.47247


In this case we do not make a back cut.


be = 0;


And hence the maximum volume is 52.5138 cm^3 as seen below.


rv[ae]


52.5138


A comparision between the back cut method and the square cut method shows that the former gives greater volume. 


We note that we indeed get a greater volume by permitting the back cut for the volume in that case is 61.2466 cm^3.


We now draw a picture of the figure resulting from the simple case - presuming we lay the flat sheet on the x-y plane with one vertex at the origin and the 8 cm side along the x- and the 10 cm side along the y-axis.  Pi' are the points in the flat sheet which we cut into and form the bottom vertices of the box and the Qi's are the resulting top vertices.


P1 = {ae,ae,0}; P2 = {ae,10-ae,0}; 

P3 = {8-ae,10-ae,0}; P4 = {8-ae,ae,0};

Q1 = {ae-be,ae-be,Sqrt[ae^2 - be^2]}; 

Q2 = {ae-be,10-ae+be,Sqrt[ae^2 - be^2]};

Q3 = {8-ae+be,10-ae+be,Sqrt[ae^2 - be^2]};

Q4 = {8-ae+be,ae-be,Sqrt[ae^2 - be^2]}; 


pics = Show[Graphics3D[{PointSize[.02], Point[P1], 

     Point[P2], Point[P3], Point[P4],Point[Q1], 

     Point[Q2], Point[Q3], Point[Q4], 

     Thickness[.01], Line[{P1,P2}], Line[{P2,P3}], 

     Line[{P3,P4}], Line[{P4,P1}], Line[{Q1,Q2}], 

     Line[{Q2,Q3}], Line[{Q3,Q4}], Line[{Q4,Q1}], 

     Line[{P1,Q1}], Line[{P2,Q2}], Line[{P3,Q3}], 

     Line[{P4,Q4}] }],Boxed->False]


General::spell1: 

   Possible spelling error: new symbol name "pics"

     is similar to existing symbol "picc".



-Graphics3D-


And finally we draw both figures together to compare them.


Show[picc,pics,Axes->True]



-Graphics3D-

ISSUES IN SOLUTION

It is probably wise to make several cut out models for students.  This will help them visualize what the cuts mean and the folding really is.  Make some exaggerated cases, indeed, some cuts which do not even give rise to solids.  Have some of the models ready for destruction, writing on them, and drawing lines and labeling variables on them.  Students will tend to assume quantities incorrectly, the height of the formed box being the most common .