Equal Arc Length (2 sub cases)

This "solution" rests on the assumption that the "best" parabola will have the same arc length as the catenary. The first step is to find this length. The following code finds this using the standard formula and taking advantage of the symmetry of the curve.

Input := 

Clear[f];
A = 68.7672;
c = 3.0022;
L = 299.2239;
fc = 625.0925;
f[x_] = fc - A (Cosh[c x/L]- 1);

Input := 

lengthcat = NIntegrate[2 Sqrt[1 + (f'[x])^2], {x, 0, L}]

Output =

1480.28

Thus, our goal is to find a parabola with arc length of 1480.28 feet.

As in the previous solution, we assume symmetry with respect to the y-axis. Thus, our parabola will not have a linear term yielding an expression of the form

Input := 

g = p1 x^2 + p2

Output =

         2
p2 + p1 x

We want to find the values p1 and p2 that will make the arc length of the parabola 1480.28 feet.

In the process of computing the arc length of g, the parameter p2 drops out resulting in

Input := 

lengthparab = Integrate[2 Sqrt[1+(2 p1 x)^2],{x, 0, L}];
p1star = p1 /. FindRoot[lengthparab == lengthcat,{p1, -1}]

Output =

-0.00723815

Thus, the leading coefficient of the "best" parabola is -0.00723815. However, it is not possible to isolate the second parameter, p2, because the parameter, in the absence of a linear term, determines vertical translation, and vertical translation does not change the arc length. Thus, we are free to choose any value of p2 we wish. There are two obvious choices:

1. Make the vertex of the parabola coincide with the apex of the arch; i.e. let p2 = fc from above.

Input := 

p2star = fc;
bestg1 =  g /. {p1 -> p1star, p2 -> p2star}

Output =

                       2
625.0925 - 0.00723815 x

Input := 

Plot[{f[x], bestg1}, {x, -L, L},
 AspectRatio -> Automatic,
 PlotStyle -> {{AbsoluteThickness[2]},
               {AbsoluteThickness[3],
                AbsoluteDashing[{3, 6}]}},
 AxesLabel -> {"[ft]", "height [ft]"}];

This graph looks pretty good near the top, but to achieve the desired arc lengths, the ends are below the ground. It is questionable whether it is fair to say the curves have the same length since the catenary is entirely above ground but the ends of the parabola are buried.

2. Make the parabola and the arch hit the ground at the same points. For this to occur, the parabola must pass through the point determined by

Input := 


root = FindRoot[f[x] == 0,{x, 300}]

Output =

{x -> 299.226}

Input := 

xint = x /. root;
p2star = p2 /. FindRoot[0 == p1star xint^2 + p2, {p2,600}]

Output =

648.079

Input := 

bestg2 = g /. {p1 -> p1star, p2 -> p2star}

Output =

                      2
648.079 - 0.00723815 x

Input := 

Plot[{f[x], bestg2}, {x, -L, L},
 AspectRatio -> Automatic,
 PlotStyle -> {{AbsoluteThickness[2]},
               {AbsoluteThickness[3],
                AbsoluteDashing[{3, 6}]}},
 AxesLabel -> {"[ft]", "height [ft]"}];

Because this parabola is entirely above ground, in one important sense it is better than the previous one.